>>  <<  Ndx  Usr  Pri  JfC  LJ  Phr  Dic  Rel  Voc  !:  wd  Help  Dictionary

II. Grammar

The following sentences illustrate the six parts of speech:
   fahrenheit=: 50
   (fahrenheit-32)*5%9
10

   prices=: 3 1 4 2
   orders=: 2 0 2 1
   orders * prices
6 0 8 2

   +/orders*prices
16

   +/\1 2 3 4 5
1 3 6 10 15

   bump=: 1&+
   bump prices
4 2 5 3
PARTS of SPEECH
50 fahrenheit       Nouns/Pronouns
+ - * % bumpVerbs/Proverbs
/ \ Adverbs
& Conjunction
( ) Punctuation
=: Copula

Verbs act upon nouns to produce noun results; the nouns to which a particular verb applies are called its arguments. A verb may have two distinct (but usually related) meanings according to whether it is applied to one argument (to its right), or to two arguments (left and right). For example, 2%5 yields 0.4 , and %5 yields 0.2 .

An adverb acts on a single noun or verb to its left. Thus, +/ is a derived verb (which might be called plus over) that sums an argument list to which it is applied, and */ gives the product of a list. A conjunction applies to two arguments, either nouns or verbs.

Punctuation is provided by parentheses that specify the sequence of execution as in elementary algebra; other punctuation includes if. do. end. as discussed under Explicit Definition (:) and Control Structures.

The word =: behaves like the copulas “is” and “are” in English, and is read as such, as in “area is 3 times 4” for area=: 3*4 . The name area thus assigned is a pronoun and, as in English, it plays the role of a noun. Similar remarks apply to names assigned to verbs, adverbs, and conjunctions. Entry of a name alone displays its value. Errors are discussed in Section II.J (Errors and Suspension).




>>  <<  Ndx  Usr  Pri  JfC  LJ  Phr  Dic  Rel  Voc  !:  wd  Help  Dictionary