m0=: median=: <.@-:@# { /:~

Median of y

m1=: tc=: (+. +./ .*.~)^:_

Transitive closure of connection matrix y

c2=: ^:

Apply function x y times

c3=: ^:

Conditional application of x if y is 0 or 1

m4=: gamma=: !@<:

Gamma function of y

d5=: beta=: *&m4 % m4@+

Beta function of x and y

d6=: pd=: ^@-@] * ^~ % !@[

Poisson distribution of states x with average number y

d7=: outof=: !

# of combs of y objects taken x at a time

d8=: ppr=: +//.@(*/)

Product of polynomials x and y

m9=: -<./"1

Move rows of table y into first quadrant

m10=: npb=: p:^:_1 

Number of primes before y

m11=: pto=: p:@i.@npb

List of primes to y

d12=: dpr=: [: 0 2 1 3&|: */

Direct matrix product of x and y

d13=: shurp=: (0 2;3 1)&|:@(*/)

Shur product of x and y

d14=: shurs=: (0 2;3 1)&|:@(+/)

Shur sum of x and y

m15=: <./ .+~

Extend distance table to next leg

d16=: +./ .*.

Extend a transitive binary relation

d17=: +/ .* % #@]

Mean of x weighted by y

d18=: -/ .%

Alternating sum of reciprocal series x%y

d19=: +/ .%

Sum of reciprocal series x%y

d20=: +/ .*

Matrix product

d21=: +/ .*

Sum over subsets of x located by y

m22=: +/ .*~

Sum of squares of y

d23=: +/ .*

Scalar (dot) product of vectors x and y

d24=: */ .^

Product over subsets of x located by y

m25=: +/@:*:

Sum of squares of y

m26=: det=: -/ .*

Determinant

m27=: (+/@(*:@(] - +/ % #)) % #)"1

Sample variance (dispersion) of y

m28=: %:@m27"1

Standard deviation of y

d29=: (+/@((]-+/@]%#@])^[)%#@])"1

x-th moment of y

m30=: m31"1

Mean of rows of table y

m31=: +/%#

Mean of list y or columns of table y