JohnRandall/ExteriorAlgebra

[Still under construction]

Introduction

We define $\Lambda^k$ , the vector space of $k$ -vectors in a real vector space $V$ of dimension $n$ . These are essentially lists $[v_1,\dots,v_k]$ for $v_i\in V$ with an equivalence relation. More precisely, we will defined a $k$ -vector as the formal symbol $v_1\wedge \dots\wedge v_k$ , the wedge product of $v_1,\dots,v_k$ .

The wedge product generalizes several ideas. Essentially, the determinant is an $n$ -vector, the wedge product of its rows, and in the case $n=3$ , $a\times b$ is $a\wedge b$ . The interpretation of the latter as a vector is misleading: this is an accident of dimension.

The reader who is interested in the concrete formulation can skip the next section.

Formal description

We define $\Lambda^k$ , the space of $k$ -vectors on $\mathbf{R}^n$ , for $k=0,1,2,\dots$ as follows. Each $\Lambda^k$ is a vector space. The bottom dimension spaces are given by $\Lambda^0=\mathbf{R}$ and $\Lambda^1=V$ . For $k>0$ , we define $\Lambda^k$ , as follows: Every element of $\Lambda^k$ can be written (non uniquely) as a formal symbol $v_1\wedge\dots\wedge v_k,$ where $\wedge$ is multilinear, antisymmetric and associative which satisfies the conditions:

$\wedge$ is linear in each of the .
If and are vector in , then $v\wedge w=-w\times v$ , and $v\wedge v=0$ (antisymmetry).
If $v_1,\dots v_k$ are linearly dependent, then $v_1\wedge\dots\wedge v_k=0$ .

A basis for $\Lambda^k$ can be given as follows. Let $e_1,\dots,e_n$ be an ordered basis for $V$ (the ordering corresponds to a choice of handedness). Then each $v_j$ can be written as a linear combination $v_j=\sum v_{ji}e_i$ , and a basis for $\Lambda^k$ is given by of ordered $k$ -fold wedge products of the basis for $V$ given by $e_{i_1}\wedge e_{i_2}\wedge e_{i_k}$ , where $i_1<i_2<\dots i_k$ . This gives the dimension of $\Lambda^k$ as $n\choose k$ . For $k>n$ , any set of $k$ vectors must be linearly dependent, so $\Lambda^k=0$ .

The exterior algebra of $\mathbf{R}^n$ is $\Lambda^0\oplus \Lambda^1\oplus\dots\oplus \Lambda^n$ .

Regardless of the basis, there is a natural homomorphism $\wedge :\Lambda^p\times\Lambda^q\to \Lambda^{p+q}$ . If $\mathbf{R}^n$ has an inner product, there is also a natural isomorphism $*:\Lambda^k\to \Lambda^{n-k}$ (Hodge duality). This is important when interpreting cross product in $\mathbf{R}^3$ .

Concrete interpretation

A $k$ -vector in $\mathbf{R}^n$ can be represented (non uniquely) as a $k\times n$ matrix, so

  ]A=:3 5 $ ? 15#10
6 4 0 6 4
9 8 5 7 4
0 1 2 7 9

represents a 3-vector in $\mathbf{R}^5$ .

There is a product, called wedge product, that given a $p$ -vector and a $q$ -vector, produces a $(p+q)$ -vector. In terms of matrices, this is just given by concatenation.

  wedge=:,
  ]B=:2 5 $ ? 10#10
3 2 1 2 9
5 3 9 6 9

   A wedge B
6 4 0 6 4
9 8 5 7 4
0 1 2 7 9
3 2 1 2 9
5 3 9 6 9

This representation is not unique. If $V$ is a $k$ -vector represented by a matrix $M$ , then

(a) =0 if the rows of are linearly dependent
(b) swapping two rows of replaces by (antisymmetry)
(c) multiplying a row of by a constant multiplies by that constant (multilinearity)
(d) adding a multiple of one row of to another does not change

A basis for the space of $k$ -vectors is given by $k$ -fold wedge products of distinct vectors of size $n$ with exactly $k$ ones, lexicographically ordered. Consequently the vector space has dimension k!n . For example,

0 1 0 1
0 1 1 0

is one of the basis vector for 2-vectors in $\mathbf{R}^4$ .

With respect to this basis, the coordinates of a $k$ -vector $V$ represented by a matrix $M$ are obtained by for a basis vector $e$ can be calculated by using $e$ to select $k$ columns of $M$ and then taking the determinant of the resulting matrix.

det=:-/ .*

cols=:{&.|:

comb=: 4 : 0
 k=. i.>:d=.y-x
 z=. (d$<i.0 0),<i.1 0
 for. i.x do. z=. k ,.&.> ,&.>/\. >:&.> z end.
 ; z
)

coords=:det@cols"1 _~ comb/@: $

   ]C=: 2 5 $ i.10
0 1 2 3 4
5 6 7 8 9
   coords C
_5 _10 _15 _20 _5 _10 _15 _5 _10 _5

Determinant

The space of $n$ -vectors in $\mathbf{R}^n$ has a single coordinate. If $M$ represents an $n$ -vector $V$ , then its coordinate is $\det M$ .

Levi-Civita symbol

The Levi-Civita symbol or complete tensor gives the wedge product of $n$ basis vectors in $\mathbf{R}^n$ . These need not be distinct, and order matters. If I is a list of numbers in i.n of length n , then M =:I {=@. i. n is a matrix representing an $n$ -vector $V,$ the wedge product of the corresponding basis elements, and so has one coordinate $c$ . By the rules for equivalence of k-vectors:

If I has repeated indices, then $c=0$ .

Otherwise I is a permutation of i.n , and $c$ is the parity of I { i.n.

The calculation is given by the complete tensor CT.

CT   =: C.!.2 @ (#:i.) @ $~

I=:0 2 1
 
  ]M=:I { =@i.3  
1 0 0
0 0 1
0 1 0
   coords M
_1
   (< I) { CT 3
_1
   J=:0 2 2
   coords J { =@i.3
0
   (< J) { CT 3
0

Cross product

If $a$ and $b$ are vectors in $\mathbf{R}^3$ , $a\wedge b$ is a 2-vector, while $a\times b$ is a 1-vector. We can reconcile these by considering $\mathbf{i},\mathbf{j},\mathbf{k}$ the standard ordered orthonormal basis for $\mathbf{R}^3$ , The ordering corresponds to the right hand rule.

We can then identify a 2-vector with a 1-vector by defining an operation $*$ given by its action on the basis:

$*(\mathbf{i}\wedge \mathbf{j})=\mathbf{k}$ , $*(\mathbf{j}\wedge \mathbf{k})=\mathbf{i}$ , $*(\mathbf{k}\wedge \mathbf{i})=\mathbf{j}$ .

   i=:,: 1 0 0
   j=:,: 0 1 0
   k=:,: 0 0 1


   star=:1 _1 1 * |. @ coords

   cross=:star @ wedge

   (i cross j),(j cross k),:(k cross i)
0 0 1
1 0 0
0 1 0

(,:1 2 3) cross (,: 4 5 6)
_3 6 _3

Area and volume

Coming soon.