## o. y (Pi Times)

Returns (πy) given any real number: y.

```   o.1
3.14159
o. i.5
0 3.14159 6.28319 9.42478 12.5664```

If y is complex, multiplies both real and imaginary parts by π

```   o. 2j1
6.28319j3.14159```

### Common uses

Sample definitions:

```   sin=: 1&o.   NB. see below: dyadic (o.)
pi=: o. : ([ * [: o. ])
r=: 10```

1. Represent in J common physics expressions involving π

```   pi 0 1 2
0 3.14159 6.28319
2 pi r
62.8319```

You can also use J's 'p'-notation to accurately represent expressions involving π

```   1p1          NB. pi
3.14159
3p2          NB. 3 times pi-squared
29.6088
3* (1p1)^2   NB. (equiv)
29.6088```

```   rfd=: 180 %~ o.   NB. radians from degrees
dfr=: rfd^:_1     NB. degrees from radians

rfd 180
3.14159
dfr 1p1
180
dfr 0.5p1
90```

## x o. y (Circle Function)

Combines the common trigonometric and hyperbolic functions, and their inverses, without the need for reserved words.

```   cop=: 0&o.        NB. sqrt (1-(y^2))
sin=: 1&o.        NB. sine of y
cos=: 2&o.        NB. cosine of y
tan=: 3&o.        NB. tangent of y
coh=: 4&o.        NB. sqrt (1+(y^2))
sinh=: 5&o.       NB. hyperbolic sine of y
cosh=: 6&o.       NB. hyperbolic cosine of y
tanh=: 7&o.       NB. hyperbolic tangent of y
conh=: 8&o.       NB. sqrt -(1+(y^2))
real=: 9&o.       NB. Real part of y
magn=: 10&o.      NB. Magnitude of y
imag=: 11&o.      NB. Imaginary part of y
angle=: 12&o.     NB. Angle of y

arcsin=:  _1&o.   NB. inverse sine
arccos=:  _2&o.   NB. inverse cosine
arctan=:  _3&o.   NB. inverse tangent
cohn=:    _4&o.   NB. sqrt (_1+(y^2))
arcsinh=: _5&o.   NB. inverse hyperbolic sine
arccosh=: _6&o.   NB. inverse hyperbolic cosine
arctanh=: _7&o.   NB. inverse hyperbolic tangent
nconh=:   _8&o.   NB. -sqrt -(1+(y^2))
same=:    _9&o.   NB. y
conj=:    _10&o.  NB. complex conjugate of y
jdot=:    _11&o.  NB. j. y
expj=:    _12&o.  NB. ^ j. y```

### Common uses

1. To work with trigonometric functions.

2. To manipulate screen graphics.

3. cop offers occasional convenience in modifying circle functions to work with complementary y

• likewise coh for hyperbolic functions

cop leverages the identity: assert 1 -: (*: sin y) + (*: cos y) for all y

```   sin rfd 30
0.5
cop@sin rfd 60
0.5```

4. Euler's Identity:

```   1 + expj 1p1
0```