>>  <<  Usr  Pri  JfC  LJ  Phr  Dic  Voc  !:  Help  Dictionary

Copula =. Local =: Global

The copula is used to assign a referent to a name, as in a=:3 and in sum=:+/ . The copula =. is local as discussed under Explicit Definition (:), and =: is global, except that global assignment to a local name is not permitted and an assignment to a locative is always global.

Copulas may also be used indirectly, with the name or names specified as a character or boxed list. If y is the expression to the right of the copula, then a single name is assigned y , otherwise each name is assigned >y if y is an atom, otherwise the i-th name is assigned >i{y . If the character list begins with ` then gerund referents are evoked.
 

For example:
   f=: 3 : 0
a=. +:y
b=: *:a
10*b
)

   a=: b=: 678
   a,b
678 678

   f 3 
360

   a,b 
678 36

   x=: 'abc';'c'
   (x) =: 3 4 ; 5 6 7
   abc
3 4
   c
5 6 7
Note that the parentheses around the name x force it to be evaluated before the assignment specified by the copula is effected.
   'alpha beta'=: i.2 4
   alpha
0 1 2 3

   beta 
4 5 6 7

   '`sum sqrt'=: +/ ` %:
   sum 3 1 4 2
10
   sqrt 2
1.41421

>>  <<  Usr  Pri  JfC  LJ  Phr  Dic  Voc  !:  Help  Dictionary